home *** CD-ROM | disk | FTP | other *** search
/ Compendium Deluxe 1 / LSD Compendium Deluxe 1.iso / a / programming / assembly / bootmenu2.lha / paz / Bootmenu.s
Encoding:
Text File  |  1993-04-18  |  20.8 KB  |  692 lines
  1. ; BootMenu by J Davis 09/1990
  2. ;
  3. ; version 1.0 - beta 05
  4. ;
  5. ; assembled using HiSoft DevPac v2
  6. ;
  7. ; a little program to allow choice of NTSC/PAL screen mode
  8. ; and expansion boards enabled/disabled at boot-time
  9. ;
  10. ; hangs around via both cool and coldcapture (see note 1)
  11. ;
  12. ; on each reboot puts up a menu allowing mode choice
  13. ;
  14. ; if there's no input in 10 secs, it defaults to the left most
  15. ; option ( PAL and boards ON respectively )
  16. ;
  17. ;
  18. ; note 1 : on machines with 1mb of chip, due to a slight oversight
  19. ;          in the 1.3/1.2 kickstart reset routine, EVERY reboot causes
  20. ;       a TOTAL system rebuild. This of course makes it hard to make
  21. ;          our code hang around.
  22. ;
  23. ;         Hence, we add a coldcapture handler that fixes the bug,
  24. ;          then run our menu routine of coolcapture
  25. ;
  26. ;          Hence our coldcapt routine also acts as an IMPROVED setpatch R,
  27. ;          in that two reboots in a row KILLS setpatch r, wheras ours,
  28. ;          hangs around and hence protects RAD: properly. Therefore 
  29. ;          DO NOT use SetPatch r and BootMenu at the same time!
  30. ;
  31. ;
  32. ; note 2 : if do_addemem is set to 1, this will build a version
  33. ;          that does an addmem of memory on the ronin 020 board
  34. ;          on the fly, due to the ronin mem not being dma-able we
  35. ;          have to set a low pri on the mem
  36. ; 
  37.  
  38.         ; turn on debug info and turn off optimising
  39.         OPT    D+
  40.         OPT     O-
  41.  
  42. ;======================
  43.  
  44. do_addmem    equ    0    ; flag for whether we do an addmem
  45.                 ; for hurricane board as well
  46.  
  47. ;======================
  48.  
  49.  
  50.     IFNE    do_addmem=1
  51.         FORMAT 0-,1-,2-
  52.         LIST
  53.         ; building PBMC_BootMenu
  54.         NOLIST
  55.         output    PBMC_BootMenu
  56.     ELSEIF
  57.         FORMAT 0-,1-,2-
  58.         LIST
  59.         ; building normal BootMenu
  60.         NOLIST
  61.         output    bootmenu
  62.     ENDC    
  63.  
  64. chip_addr    equ    $40000    ; where we swap our chip data to/from
  65.  
  66. ; process structure offsets
  67.  
  68. pr_cli        equ    $0Ac    ; process cli flag offset
  69. pr_msgport    equ    $05c    ; process msgport offset
  70.  
  71. ; execbase structure offsets
  72.  
  73. coldcapture    equ    $02a
  74. coolcapture    equ    $02e
  75. sysstklower    equ    $03a
  76.         
  77. ; misc library functions
  78.  
  79. forbid        equ    -$084    ; offsets for various exec and int calls
  80. getmsg        equ    -$174    ; saves long includes and compile times
  81. replymsg    equ    -$17a
  82. waitport    equ    -$180
  83. findtask    equ    -$126
  84. autoreq        equ    -$15c
  85. openlib        equ    -$228
  86. closelib    equ    -$19e
  87.  
  88. output        equ    -$003c        
  89. write        equ    -$0030
  90.  
  91. openlibrary    equ    -$0228
  92. closelibrary    equ    -$019e
  93.  
  94. addmemlist     equ    -618    
  95.  
  96. ; hardware equates 
  97.  
  98. potgor        equ    $dff016
  99. potgo        equ    $dff034
  100.  
  101. intreq        equ    $dff09c
  102. intreqr        equ    $dff01e
  103.  
  104. ddfstart    equ    $dff092
  105. ddfstop        equ    $dff094
  106.  
  107. diwstart    equ    $dff08e
  108. diwstop        equ    $dff090
  109.  
  110. bpl1mod        equ    $dff108
  111.  
  112. bplcon1        equ    $dff102
  113. bplcon0        equ    $dff100
  114.  
  115. r_color0    equ    $0180
  116. r_color1    equ    $0182
  117.  
  118. r_bpl1pth    equ    $00e0
  119. r_bpl1ptl    equ    $00e2
  120.  
  121. cop1lch        equ    $dff080
  122. cop1lcl        equ    $dff082
  123. copjmp1        equ    $dff088
  124.  
  125. dmacon        equ    $dff096
  126.  
  127. agnusdetect    equ    $dff004
  128.  
  129. ;==============================================================
  130.  
  131. startup:    ; startup code - determine if run from wb/cli etc
  132.     
  133.         move.l    $4,a6
  134.         move.l    #0,a1
  135.         jsr    findtask(a6)        ; find ourselves
  136.  
  137.         move.l    d0,a4            ; save our process pointer
  138.  
  139.         move.l    pr_cli(a4),d0
  140.         bne    fromdos            ; was a DOS startup
  141.  
  142.         ; was started from WB
  143.  
  144. fromwb:        lea    pr_msgport(a4),a0
  145.         jsr    waitport(a6)        ; wait for startup msg
  146.         lea    pr_msgport(a4),a0
  147.         jsr    getmsg(a6)        ; get the wb msg
  148.  
  149.         move.l    d0,wbmsg        ; save pointer to our startup msg
  150.         move.l    #1,wb            ; flag we started from wb
  151.  
  152.         lea    intuiname,a1
  153.         move.l    #0,d0
  154.         move.l    $4,a6
  155.         jsr    openlib(a6)         ; open intuition lib
  156.  
  157.         move.l    d0,a6            ; save ibase
  158.         
  159.         move.l    #0,a0            ; window to display in
  160.         move.l    #bodyitext1,a1        ; body text
  161.         move.l    #gaditext,a2         ; postive text
  162.         move.l    #gaditext,a3          ; negative text
  163.         move.l    #0,d0            ; pflags
  164.         move.l    #0,d1            ; nflags
  165.         move.l    #370,d2            ; width
  166.         move.l    #80,d3            ; height
  167.         jsr    autoreq(a6)        ; request user confirmation
  168.  
  169.         move.l    a6,a1            ; close intuition lib
  170.         move.l    $4,a6
  171.         jsr    closelib(A6)
  172.  
  173.         bsr    install            ; install ourselves
  174.  
  175.         bra    exit
  176.  
  177. fromdos:    ; was run from dos - output message to stdout
  178.  
  179.         move.l    $4,a6
  180.         lea    dosname,a1
  181.         move.l    #$0,d0
  182.         jsr    openlibrary(a6)         ; open dos library
  183.         
  184.         move.l    d0,a6             ; save dos base
  185.         
  186.         jsr    output(a6)         ; get handle on stdout
  187.         
  188.         move.l    d0,d1             ; get file handle
  189.         move.l    #msgtxt,d2
  190.         move.l    #etext-msgtxt,d3
  191.         jsr    write(a6)         ; put up a message saying we're installed
  192.         
  193.         move.l    $4,a6
  194.         move.l    a6,a1
  195.         jsr    closelibrary(a6)     ; close dos
  196.  
  197.         bsr    install        
  198.  
  199. exit:        move.l    wb,d0
  200.         cmp.l    #0,d0            ; was this a CLI invocation
  201.         beq    exit_dos        ; DOS - just exit 
  202.  
  203.         ; workbench exit
  204.  
  205.         move.l    $4,a6
  206.         jsr    forbid(a6)        ; lock out everyone else
  207.  
  208.         move.l    wbmsg,a1
  209.         jsr    replymsg(a6)        ; reply to Wbstartup msg
  210.  
  211. exit_dos:    move.l    #0,d0            ; return with return code 0
  212.         rts            
  213.  
  214. ;=================================================
  215.         even
  216. wb:        dc.l    0            ; run mode flag 0=dos process 1=wbprocess
  217. wbmsg:        dc.l    0            ; where we save our workbench msg
  218.  
  219.         even
  220. intuiname:    dc.b    "intuition.library",0
  221.         
  222.         even
  223. dosname:    dc.b    "dos.library",0
  224.  
  225.         ; message we output for cli startup
  226.     IFNE    do_addmem=1
  227. msgtxt:        dc.b    27,"[33mBootMenu PBMC",27,"[0m, by J Davis 09/1990",10
  228.     ELSEIF
  229. msgtxt:        dc.b    27,"[33mBootMenu v1.0",27,"[0m, by J Davis 09/1990",10
  230.     ENDC
  231.         dc.b    "installed ok - menu will become active at next reboot",10,0
  232. etext:        dc.b    0
  233.  
  234.         even
  235.  
  236.         ; stuff for our autorequester for wb usage
  237. bodyitext1:    dc.b    2           ; front pen
  238.         dc.b    1           ; back pen
  239.         dc.b    0           ; draw mode
  240.         dc.w    40           ; leftedge
  241.         dc.w    6           ; topedge
  242.         dc.l    0           ; textattr = default
  243.         dc.l    bodytext1      ; actual text
  244.         dc.l    bodyitext2         ; next
  245.  
  246. bodyitext2:    dc.b    3           ; front pen
  247.         dc.b    0           ; back pen
  248.         dc.b    0           ; draw mode
  249.         dc.w    120           ; leftedge
  250.         dc.w    26           ; topedge
  251.         dc.l    0           ; textattr = default
  252.         dc.l    bodytext2      ; actual text
  253.         dc.l     bodyitext3    ; next
  254.  
  255. bodyitext3:    dc.b    3           ; front pen
  256.         dc.b    0           ; back pen
  257.         dc.b    0           ; draw mode
  258.         dc.w    20           ; leftedge
  259.         dc.w    36           ; topedge
  260.         dc.l    0           ; textattr = default
  261.         dc.l    bodytext3      ; actual text
  262.         dc.l    0         ; next
  263.  
  264. gaditext:    dc.b    0        ; front pen
  265.         dc.b    0        ; back pen
  266.         dc.b    0        ; draw mode
  267.         dc.w    4        ; leftedge
  268.         dc.w    4        ; topedge
  269.         dc.l    0        ; textattr = default
  270.         dc.l    gadtext        ; actual text
  271.         dc.l    0        ; next
  272.         
  273.         ; actual text for our requester
  274.  
  275.     IFNE    do_addmem=1
  276. bodytext1:    dc.b    "BootMenu PBMC, by J Davis 09/1990",0
  277.         ELSEIF
  278. bodytext1:    dc.b    "BootMenu v1.0, by J Davis 09/1990",0
  279.     ENDC
  280. bodytext2:    dc.b    "installed ok",0
  281. bodytext3:    dc.b    "menu will become active at next reboot",0
  282. gadtext:    dc.b    "Ok",0
  283.  
  284. ;=====================================================
  285.  
  286.         even
  287.  
  288. install:    ; this routine does the actual cold/coolcapture
  289.         ; setting 
  290.  
  291.         ; works out where we're going to install to
  292.         ; then copies handler code there and hooks vectors
  293.         
  294.         move.l    $4,a6
  295.         move.l    sysstklower(A6),a0            ; get pointer to base of sys-stack
  296.         move.l    a0,codetarget                ; save pointer to address
  297.  
  298.         move.l    a0,a1
  299.         add.l    #coldcapt-captstart,a1            ; point to coldcapt address
  300.         move.l    a1,coldcaptaddr                ; save address
  301.  
  302.         move.l    a0,a1
  303.         add      #coolcapt-captstart,a1            ; point to coolcapt addres
  304.         move.l    a1,coolcaptaddr                ; save address
  305.  
  306.         ; now stuff our code away on the bottom of the system stack
  307.  
  308.         lea    captstart(pc),a1            ; code to copy
  309.         move.l    codetarget,a2                 ; where to copy to
  310.         move.l    #endcapt-captstart,d0             ; amount to copy
  311. mloop:        move.b    (a1)+,(a2)+
  312.         dbf    d0,mloop
  313.  
  314.         ; now install a vector to the copied code in execbase.coldcapture
  315.         
  316.         move.l    $4,a6                       ; get execbase
  317.         move.l    coldcaptaddr,a0                ; address of our coldcap routine
  318.         move.l    a0,coldcapture(a6)             ; set coldcapture
  319.  
  320.         move.l    coolcaptaddr,a0                ; address of our coolcap routine
  321.         move.l    a0,coolcapture(a6)            ; set coolcapture to our code
  322.  
  323.         ; finally, recalc the execbase checksum
  324.         
  325.         lea    34(a6),a0                 ; start of checksummed area in execbase
  326.         move.w    #$16,d0                     ; number of checksummed words
  327.         move.w    #$0,d1                     ; clear counter
  328.     
  329. sum:        add.w    (A0)+,d1                 ; sum execbase and update checksum
  330.         dbf    d0,sum
  331.     
  332.         not.w    d1
  333.         move.w    d1,82(a6)                 ; set new execbase checksum
  334.  
  335.         ; all done
  336.         rts
  337.  
  338.         even
  339.         
  340. codetarget:    dc.l    0
  341. coolcaptaddr:    dc.l    0
  342. coldcaptaddr:    dc.l    0
  343.         
  344. ;==============================================================
  345. ;
  346. ; our capture routines
  347. ;
  348. ; since this is going to stick around, we need to copy
  349. ; it somewhere safe - like the SysStack area
  350. ;
  351. ; since we can't guarantee sys-stack will be in chip, we 
  352. ; swap our bitplane data and copper list to chip mem on the fly
  353. ; and then swap it back out ( in case rad: was using the bit where
  354. ; we put our screen ! )
  355.  
  356.         even
  357.  
  358. captstart:    
  359.  
  360. coldcapt:    ; this is our coldcapture routine - basically
  361.         ; fixes the rebuild problem that SETPATCH R tries
  362.         ; ( but fails ) to
  363.  
  364.         ; CAUTION!! This code is _specific to kickstart 1.x
  365.         ; DO NOT USE WITH KickStart 2.x!!!
  366.  
  367.         ; important - reinsert our code into execbase, as coldcapt
  368.         ; is cleared before it's called!! this is what setpatch r
  369.         ; fails to do (and hence why it's not reliable)!
  370.  
  371.         lea    coldcapt(pc),a0                ; on entry A6=execbase
  372.         move.l    a0,coldcapture(a6)            ; reset our vector in execbase - don't need to resum
  373.  
  374.         ; the following is a kludge to get around exec 34.x
  375.         ; insisting on doing a system rebuild if >512k chip
  376.         ; it is directly based on the rom code in ks1.2/1.3
  377.         
  378.         bchg    #1,$bfe001                ; toggle led on
  379.         
  380.         move.l    $fc0010,d0                ; get ks ver no.
  381.         cmp.l    $14(a6),d0                ; compare with execbase ver
  382.         bne.s    rebuild_all
  383.  
  384.         ; the following is the bit that's wrong with ks1.x
  385.         ; now fixed to work with 1mb chipmem
  386.         
  387.         move.l    $3e(a6),a3                ; get maxchipmem
  388.         cmpa.l    #$100000,a3                ; more than 1mb chip ?
  389.         bhi.s    rebuild_all
  390.         
  391.         add.l    #$1e,a5                    ; point A5 past the (incorrect) code we skip
  392.         jmp    (A5)                    ; carry on with rest of boot
  393.  
  394. rebuild_all:    jmp    $fc01ce                    ; jump to rom rebuild code
  395.  
  396. ;====================================================================
  397.  
  398.         even
  399.  
  400. coolcapt:    ; our coolcapture routine - actually does the menus etc
  401.  
  402.         movem.l    d0-d7/a0-a6,-(a7)            ; save everything
  403.  
  404.         bsr    swapmem                    ; first, copy our bitplane data and copper list to chip mem
  405.  
  406.         move.w    #$ffff,potgo                 ; set for button inputs on mouse
  407.         
  408.         ; finished setting up - ask whether to turn boards off
  409.         
  410.         move.l    #chip_addr+board_mode-chipdata_start,a1    ; address where bitplane data is copied to
  411.         bsr     doscreen                ; put up screen and wait for choice
  412.  
  413.         btst    #0,d0
  414.         beq.s    next                    ; left mouse=leave on so skip
  415.  
  416.         ; user requested expansion board disable - do it
  417.  
  418.         moveq.l    #$7,d1                    ; max no boards we fix = 8 
  419.  
  420. bchk:        move.w    $e80008,d0                ; get flag byte from board
  421.         not.w    d0                    ; invert
  422.         btst.l    #14,d0                    ; see if board supports shut_up
  423.         beq.s    shut_up                    ; bit=0 means board shuts up ok
  424.  
  425.         ; board doesn't support shut up, so 
  426.         ; config board to $200000 (only gap big enough for 8mb boards)
  427.         
  428.         move.w    #$0000,$e8004a              ; fake board out to $200000
  429.         move.w    #$2000,$e80048  
  430.         
  431.         bra.s    nboard                    ; carry on
  432.  
  433. shut_up:    move.b    #$ff,$e8004c                ; tell the board to shut up
  434.  
  435. nboard:        dbf    d1,bchk                    ; loop thru all boards
  436.  
  437.         ; now query for screen mode
  438. next:        ; see if this machine has the 1mb Agnus
  439.  
  440.         move.w    agnusdetect,d0
  441.         and.w    #$2000,d0
  442.         beq.s    no_8372                    ; doesn't have obese agnus - skip screen mode choice
  443.  
  444.         ; has the 1mb agnus, offer screen mode choice
  445.  
  446.         move.l    #chip_addr+scr_mode-chipdata_start,a1    ; address where bitplane data is copied to
  447.         bsr    doscreen                ; put up screen and wait for choice
  448.  
  449.         btst    #0,d0                    ; left mouse = PAL
  450.         beq.s    go_pal
  451.  
  452.         move.w    #$0000,$dff1dc                ; set NTSC mode on agnus
  453.         bra.s    no_8372
  454.  
  455. go_pal:        move.w    #$0020,$dff1dc                ; set PAL mode on agnus
  456.         
  457. no_8372:    bsr    swapmem                    ; finally restore chipmem    
  458.  
  459.     IFNE do_addmem=1 
  460.     
  461.         FORMAT    0-,1-,2-
  462.         LIST
  463.         ; adding special addmem code!
  464.         NOLIST
  465.         
  466.         ; Addmem the 32 bit mem on the Ronin 020 board
  467.         ; into the system
  468.         ;
  469.         ; we add 1mb, starting at $600000
  470.  
  471.         move.l    $4,a6        ; get execbase
  472.         move.l    #$100000,d0    ; amount of mem we're adding ( 1mb )
  473.         move.l    #$5,d1        ; attributes ( memf_fast | memf_public )
  474.         move.l    #-20,d2        ; pri of mem must be low so as to force HD to use chip!!!
  475.         move.l    #$600000,a0    ; where the mem starts ( 6 mb )
  476.         move.l    #0,a1        ; pointer to a name for this block 
  477.                     ; don't want one so pass NULL
  478.         jsr    addmemlist(a6)    ; do the deed !!!            
  479.  
  480.         ; you need to be careful after this to NOT run the 
  481.         ; ronin addmem prog - as otherwise you will get the 
  482.         ; same block of mem added TWICE ( can you say 'guru' ? :-)
  483.     ENDC
  484.  
  485.         movem.l    (A7)+,d0-d7/a0-a6            ; get back all regs
  486.         rts
  487.  
  488.  
  489. ; ===============================
  490. ; this routine swaps chipdata into/out of a block of chipmem
  491.  
  492. swapmem:    lea    chipdata_start(pc),a0            ; where to copy from
  493.         move.l    #chip_addr,a1                ; where we copy to
  494.         move.l    #chipdata_end-chipdata_start,d0        ; amount to copy
  495.  
  496. cm_loop:    move.b    (a0),d1                    ; we exchange data in and out
  497.         move.b    (a1),d2            
  498.         move.b    d2,(a0)+
  499.         move.b    d1,(a1)+
  500.         dbf    d0,cm_loop
  501.         
  502.         rts
  503.  
  504.  
  505. ;====================================
  506. ; this subroutine puts up the screen pointed to by a1
  507. ; and return d0=0 for left mouse and d0<>0 for right mouse
  508. ; also trashes d1
  509.  
  510. doscreen:    ; setup screen hardware
  511.  
  512.         move.w    #$1200,bplcon0                ; set for lores, 1 plane
  513.         move.w    #$0000,bplcon1
  514.         
  515.         move.w    #$0000,bpl1mod                ; modulo = 0
  516.         
  517.         move.w    #$0038,ddfstart                ; data fetch start
  518.         move.w    #$00d0,ddfstop                 ; data fetch stop
  519.         
  520.         move.w    #$7081,diwstart                ; display window start
  521.         move.w    #$89b0,diwstop                ; display window stop
  522.         
  523.         move.l    a1,d0                    ; setup up copper list bitplane pointers
  524.         move.w    d0,chip_addr+screen_l-chipdata_start    ; point cop1l load addr to right place
  525.         swap    d0
  526.         move.w    d0,chip_addr+screen_h-chipdata_start    ; point cop1h load addr to right place
  527.  
  528.         move.l    #chip_addr+ourcoplist-chipdata_start,cop1lch ; point copper at our copper list
  529.         
  530.         move.w    copjmp1,d0                ; force copper to our list
  531.         
  532.         move.w    #%1000000110000000,dmacon        ; enable bitplane and copper dma
  533.         
  534.         move.w    #10*50,d1                ; 10 secs worth of vblanks before timeout
  535.  
  536. waittof:    move.w    intreqr,d0
  537.         btst    #5,d0                    ; vblank int ?
  538.         beq.s    waittof                    ; wait until tof true
  539.     
  540.         move.w    #$0020,intreq                ; clear int
  541.         
  542.         btst    #6,$bfe001                ; left button down ?
  543.         beq.s    lmb
  544.         
  545.         btst    #10,potgor                ; right button down
  546.         beq.s    rmb
  547.  
  548.         subq.w    #$1,d1                    ; dec frame counter
  549.         cmp.w    #$0,d1                    ; time up ?
  550.         beq.s    lmb                    ; default to left mouse button
  551.         
  552.         bra.s    waittof        
  553.         
  554. lmb:        moveq    #0,d0
  555.         bra.s    _exit_1
  556.             
  557. rmb:        moveq    #1,d0
  558.  
  559. _exit_1:    ; debounce buttons to avoid 'fallthru' - wait for both buttons up
  560.  
  561.         btst    #10,potgor
  562.         beq    _exit_1                    ; wait for user to let go of rmb
  563.         
  564.         btst    #6,$bfe001
  565.         beq    _exit_1                    ; wait for user to let go of rmb
  566.  
  567.         ; now delay 15 vblanks to allow buttons to settle
  568.         
  569.         move.w    #15,d2
  570.         
  571. _1waittof:    move.w    intreqr,d1
  572.         btst    #5,d1                    ; vblank int ?
  573.         beq.s    _1waittof                ; wait until tof true
  574.     
  575.         move.w    #$0020,intreq                ; clear int
  576.  
  577.         subq.w    #1,d2                    ; dec delay counter
  578.         cmp.w    #$0,d2
  579.         bne    _1waittof
  580.         
  581.         move.w    #%0000000110000000,dmacon        ; disable bitplane and copper dma
  582.  
  583.         rts
  584.  
  585. ;=========================================
  586.  
  587.         ; message for people running VMK etc 
  588.  
  589.         dc.b    "  BootMenu v1.0 J Davis - this is NOT a virus!!!  "
  590.         
  591. ;=========================================
  592.  
  593.         even
  594.  
  595. chipdata_start:
  596.         
  597. ourcoplist:    ; the following copperlist runs our screen
  598.  
  599.         dc.w    r_bpl1pth
  600. screen_h    dc.w    0        ; set high bitplane address
  601.  
  602.         dc.w    r_bpl1ptl
  603. screen_l    dc.w    0        ; set low bitplane address
  604.  
  605.         dc.w    r_color0
  606.         dc.w    $0026        ; set background 
  607.  
  608.         dc.w    $6f01,$ff00    ; wait for top of our display
  609.         
  610.         dc.w    r_color1
  611.         dc.w    $0fff        ; set fg 
  612.  
  613.         dc.w    $7101,$ff00    ; wait til after top line
  614.  
  615.         dc.w    r_color1
  616.         dc.w    $0f08        ; set fg 
  617.  
  618.         dc.w    $7c01,$ff00    ; wait for next bit of text
  619.  
  620.         dc.w    r_color1
  621.         dc.w    $006c        ; set fg
  622.  
  623.         dc.w    $8801,$ff00    ; wait for bottom line
  624.  
  625.         dc.w    r_color1
  626.         dc.w    $0fff        ; set fg
  627.  
  628.         dc.w    $ffff,$fffe    ; wait for next TOF
  629.         
  630.         ; the following is the bit map for out first screen
  631.  
  632. board_mode:    dc.l    $ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff
  633.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  634.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  635.         dc.l    $0000038C,$60000000,$0000000F,$E0000000,$00018000,$000FC000,$0000E000,$00000000,$00000000,$00000000
  636.         dc.l    $000006CE,$60000000,$00000006,$60000000,$00000000,$00066000,$00006000,$00000000,$71FDFC00,$00000000
  637.         dc.l    $0007EC6F,$67E00000,$00000006,$063DC3C7,$C3E383C7,$C00663C3,$CEC363E0,$00000000,$D8CCCC00,$00000000
  638.         dc.l    $07E00C6D,$E007E000,$00000007,$83666066,$66018666,$6007C660,$6766E600,$000000FD,$8CC0C0FC,$00000000
  639.         dc.l    $00000C6C,$E0000000,$00000006,$01C661E6,$63C18666,$60066661,$E66663C0,$0000FC01,$8CF0F000,$FC000000
  640.         dc.l    $0007E6CC,$67E00000,$00000006,$6367C666,$60618666,$60066666,$66066060,$00000001,$8CC0C000,$00000000
  641.         dc.l    $0000038C,$60000000,$0000000F,$E63603B6,$67C3C3C6,$600FC3C3,$BF03B7C0,$000000FC,$D8C0C0FC,$00000000
  642.         dc.l    $00000000,$00000000,$00000000,$000F0000,$00000000,$00000000,$00000000,$00000000,$71E1E000,$00000000
  643.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  644.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  645.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  646.         dc.l    $000007E0,$00004000,$00000006,$18C001E0,$07E00000,$7007C000,$00C00001,$E1E018C1,$E1E1E000,$00000000
  647.         dc.l    $00000330,$0000C000,$00000006,$19C00330,$03300000,$30036000,$00000003,$333031C3,$33333000,$00000000
  648.         dc.l    $00000331,$E1E1F331,$E3E33003,$30C00370,$03333000,$300331E3,$31C1F003,$733060C3,$33337000,$00000000
  649.         dc.l    $000003E3,$3330C3BB,$33333003,$30C003F0,$03E33000,$30033033,$30C30003,$F1F0C0C1,$F1F3F000,$00000000
  650.         dc.l    $00000333,$3330C35B,$F3333001,$E0C003B0,$03333003,$300330F3,$30C1E003,$B03180C0,$3033B000,$00000000
  651.         dc.l    $00000333,$3330D31B,$03333001,$E0C0C330,$0331E003,$30036331,$E0C03003,$306300C0,$60633000,$00000000
  652.         dc.l    $000007E1,$E1E06319,$E331D800,$C3F0C1E0,$07E0C001,$E007C1D8,$C1E3E001,$E1C603F1,$C1C1E000,$00000000
  653.         dc.l    $00000000,$00000000,$00000000,$00000000,$00038000,$00000000,$00000000,$00000000,$00000000,$00000000
  654.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  655.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  656.         dc.l    $ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff
  657.         
  658.         ; the following is the bitmap for our second screen
  659.         
  660. scr_mode:    dc.l    $ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff
  661.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  662.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  663.         dc.l    $000007E0,$C7800000,$00000000,$00001E00,$00000000,$00410007,$00000000,$0000018C,$FC787800,$00000000
  664.         dc.l    $00000331,$E3000000,$00000000,$00003300,$00000000,$00630003,$00000000,$000001CC,$B4CCCC00,$00000000
  665.         dc.l    $0003F331,$E303F000,$00000000,$0000381E,$761E1E3E,$00771E1B,$1E000000,$0000FDEC,$30E180FC,$00000000
  666.         dc.l    $03F003E3,$330003F0,$00000000,$00001C33,$3B333333,$007F3337,$33000000,$00FC01BC,$30718000,$FC000000
  667.         dc.l    $00000303,$F3100000,$00000000,$00000730,$333F3F33,$006B3333,$3F000000,$0000019C,$301D8000,$00000000
  668.         dc.l    $0003F306,$1B33F000,$00000000,$00003333,$30303033,$00633333,$30000000,$0000FD8C,$30CCCCFC,$00000000
  669.         dc.l    $00000786,$1FF00000,$00000000,$00001E1E,$781E1E33,$00631E1D,$9E000000,$0000018C,$78787800,$00000000
  670.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  671.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  672.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  673.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  674.         dc.l    $000007E0,$00004000,$00000006,$18C001E0,$07E00000,$7007C000,$00C00001,$E1E018C1,$E1E1E000,$00000000
  675.         dc.l    $00000330,$0000C000,$00000006,$19C00330,$03300000,$30036000,$00000003,$333031C3,$33333000,$00000000
  676.         dc.l    $00000331,$E1E1F331,$E3E33003,$30C00370,$03333000,$300331E3,$31C1F003,$733060C3,$33337000,$00000000
  677.         dc.l    $000003E3,$3330C3BB,$33333003,$30C003F0,$03E33000,$30033033,$30C30003,$F1F0C0C1,$F1F3F000,$00000000
  678.         dc.l    $00000333,$3330C35B,$F3333001,$E0C003B0,$03333003,$300330F3,$30C1E003,$B03180C0,$3033B000,$00000000
  679.         dc.l    $00000333,$3330D31B,$03333001,$E0C0C330,$0331E003,$30036331,$E0C03003,$306300C0,$60633000,$00000000
  680.         dc.l    $000007E1,$E1E06319,$E331D800,$C3F0C1E0,$07E0C001,$E007C1D8,$C1E3E001,$E1C603F1,$C1C1E000,$00000000
  681.         dc.l    $00000000,$00000000,$00000000,$00000000,$00038000,$00000000,$00000000,$00000000,$00000000,$00000000
  682.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  683.         dc.l    $00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000,$00000000
  684.         dc.l    $ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff,$ffffffff
  685.  
  686. chipdata_end:
  687.  
  688. endcapt:    
  689.  
  690.         END
  691.  
  692.